home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / yase.arc / GROUP2.ASM < prev    next >
Encoding:
Assembly Source File  |  1986-12-13  |  7.5 KB  |  225 lines
  1. ******************************************************************
  2. * COPYRIGHT (C) 1986 by Donald Krantz and James Stanley
  3. * - Note: This is a real, live, actual, registered copyright,
  4. *   and should be treated as such. This source code is from
  5. *   the book "68000 Assembly Language", Krantz and Stanley,
  6. *   Addison-Wesley Publishing Company, Reading, MA, 1986.
  7. * 
  8. *   Permission granted by the authors for non-commercial use
  9. *   in programs released to the public domain, as long as this
  10. *   copyright notice remains attached and visible.
  11. *
  12. *****************************************************************
  13. * GROUP 2 (Block) Commands
  14.  
  15.     xref    _getkey,ask,case,chk_blk,cnt_nl,default,dirty
  16.     xref    p_buf,p_cnt,prompt,putfile,query,readfile,seek
  17.     xref    writefile
  18.     xdef    group_2
  19.  
  20. #edit.h
  21. #cursor.h
  22. *****************************************************************
  23. * GROUP_2 - group 2 (block) commands
  24. group_2:
  25.     move.l    #k_cmd,a0    * load up prompt address
  26.     bsr    prompt        * output prompt
  27.     bsr    _getkey        * get switch key
  28.     and.w    #$001F,d0    * make u/l, l/c letters cntrl
  29.     move.l    #table2,a0    * load up case table address
  30.     bra    case        * returns to caller of group_2
  31. k_cmd:    dc.b    'Block Command: B C D P Q R S V W Y X',0
  32.     dc.w    0
  33. *****************************************************************
  34. * TABLE2 - switch table for group 2 commands
  35. table2:
  36.     dc.w    12        * number of case options
  37.     dc.w    $0B        * ^K mark block end
  38.     dc.l    mark_end
  39.     dc.w    $02        * ^B mark block start
  40.     dc.l    mark_start
  41.     dc.w    $03        * ^C copy block to cursor
  42.     dc.l    copy
  43.     dc.w    $04        * ^D end edit and save
  44.     dc.l    end_save
  45.     dc.w    $13        * ^S save and resume
  46.     dc.l    save
  47.     dc.w    $19        * ^Y cut block
  48.     dc.l    delete
  49.     dc.w    $10        * ^P Paste block
  50.     dc.l    paste
  51.     dc.w    $11        * ^Q abandon file
  52.     dc.l    abandon
  53.     dc.w    $17        * ^W write block
  54.     dc.l    write
  55.     dc.w    $12        * ^R read file
  56.     dc.l    readfile
  57.     dc.w    $16        * ^V move block
  58.     dc.l    mblock
  59.     dc.w    $18        * ^X end edit and save
  60.     dc.l    end_save
  61.     dc.l    default        * all other options
  62. *****************************************************************
  63. * MARK_END - marks the gap as the end of the block
  64. mark_end:
  65.     move.l    b_gap(a5),blk_end(a5)
  66.     rts
  67. *****************************************************************
  68. * MARK_START - marks the gap as the beginning of the block
  69. mark_start:
  70.     move.l    b_gap(a5),blk_st(a5)
  71.     rts
  72. *****************************************************************
  73. * MBLOCK - moves the marked block to the cursor
  74. mblock:
  75.     bsr    delete        * cut block
  76.     tst.w    ed_err(a5)    * check for errors
  77.     bne    sk0_mbl        * exit on error
  78.     bsr    paste        * insert block here
  79. sk0_mbl:
  80.     rts
  81. *****************************************************************
  82. * COPY - copies the marked block to the cursor
  83. copy:
  84.     bsr    chk_blk        * look for valid block
  85.     tst.w    ed_err(a5)    * look for error code
  86.     bne    sk0_cpy        * error jump out
  87.     move.l    b_gap(a5),-(a7)    * save    current cursor position
  88.     move.l    blk_end(a5),d0    * we want to have cursor at end
  89.     bsr    seek        * move to end of block
  90.     move.l    blk_st(a5),a0    * load source address
  91.     move.l    #p_buf,a1    * load destination address
  92.     move.l    blk_end(a5),d0    * calculate number of bytes
  93.     sub.l    a0,d0        * d0 is number of bytes
  94.     move.l    d0,d1        * save number of bytes
  95.     bra    sk1_cpy        * loop test before loop
  96. lp0_cpy:
  97.     move.b    (a0)+,(a1)+    * transfer bytes
  98. sk1_cpy:
  99.     dbra    d0,lp0_cpy    * loop test
  100.     move.l    (a7)+,d0    * get old cursor position
  101.     move.w    d1,p_cnt    * save byte count
  102.     bsr    seek        * go back to old cursor position
  103.     bsr    paste        * get stuff in
  104. sk0_cpy:
  105.     rts
  106. *****************************************************************
  107. * DELETE - cuts marked block and puts into paste buffer
  108. delete:
  109.     bsr    chk_blk        * look for valid block
  110.     tst.w    ed_err(a5)    * look for error code
  111.     bne    sk0_del        * error jump out
  112.     move.l    b_gap(a5),-(a7)    * save    current cursor position
  113.     move.l    blk_end(a5),d0    * we want to have cursor at end
  114.     bsr    seek        * move to end of block
  115.     move.l    blk_st(a5),a0    * load source address
  116.     move.l    #p_buf,a1    * load destination address
  117.     move.l    blk_end(a5),d0    * calculate number of bytes
  118.     sub.l    a0,d0        * d0 is number of bytes
  119.     move.l    d0,d1        * save number of bytes
  120.     bra    sk1_del        * loop test before loop
  121. lp0_del:
  122.     move.b    (a0)+,(a1)+    * transfer bytes
  123. sk1_del:
  124.     dbra    d0,lp0_del    * loop test
  125.     move.l    blk_st(a5),b_gap(a5)  ** erase block
  126.     move.l    (a7)+,d0    * get old cursor position
  127.     cmp.l    b_gap(a5),d0    * were we past cursor?
  128.     blt    sk2_del        * yes.
  129.     sub.l    d1,d0        * adjust for missing bytes
  130.     cmp.l    b_gap(a5),d0    * were we in gap?
  131.     bge    sk2_del        * no, we're ok still
  132.     move.l    b_gap(a5),d0    * fake it.
  133. sk2_del:
  134.     move.w    d1,p_cnt    * save byte count
  135.     bsr    seek        * go back to old cursor position
  136.     bsr    cnt_nl        * adjust line count
  137.     bsr    dirty        * mark file as modified
  138. sk0_del:
  139.     rts
  140. *****************************************************************
  141. * PASTE - pulls whatever's in paste buffer into cursor gap
  142. paste:
  143.     tst.w    p_cnt        * check if paste buffer used
  144.     beq    sk0_pas        * jump if empty
  145.     move.l    e_gap(a5),d0    * check for room.
  146.     sub.l    b_gap(a5),d0    * calculate gap size
  147.     cmp.w    p_cnt,d0    * test againt paste buffer
  148.     bcs    sk2_pas        * jump on error
  149.     bsr    dirty        * mark file as modified
  150.     move.l    b_gap(a5),a0    * get load address
  151.     move.l    #p_buf,a1    * get source address
  152.     move.w    p_cnt,d0    * get byte count
  153.     bra    sk3_pas        * loop test before move
  154. lp0_pas:
  155.     move.b    (a1)+,(a0)+    * transfer byte
  156. sk3_pas:
  157.     dbra    d0,lp0_pas    * loop for all bytes in p_buf
  158.     move.l    a0,b_gap(a5)    * save new gap start pointer
  159.     bsr    cnt_nl        * reset line count
  160.     bra    sk1_pas
  161. sk2_pas:
  162.     move.w    #10,ed_err(a5)    * load "block too large" code
  163.     bra    sk1_pas        * jump out
  164. sk0_pas:
  165.     move.w    #11,ed_err(a5)    * load "paste buffer empty" code
  166. sk1_pas:
  167.     rts
  168. *****************************************************************
  169. * WRITE - writes a marked block to disk
  170. write:    
  171.     bsr    chk_blk        * check for valid blocks
  172.     tst.w    ed_err(a5)    * look at return code
  173.     bne    sk0_wrt        * error jump
  174.     move.l    b_gap(a5),-(a7)    * save cursor position
  175.     move.l    blk_end(a5),d0    * setup for seek
  176.     bsr    seek        * seek end of block
  177.     move.l    blk_st(a5),a1    * setup for file write
  178.     move.l    blk_end(a5),d1    * compute number of bytes to write
  179.     sub.l    blk_st(a5),d1    * D1 is number of bytes in block
  180.     bsr    writefile    * go try to write file
  181.     move.l    (a7)+,d0    * now put cursor back
  182.     bsr    seek
  183. sk0_wrt:
  184.     rts
  185. *****************************************************************
  186. * SAVE - Saves file and resumes editing
  187. save:
  188.     move.l    b_gap(a5),-(a7)    * save current gap position
  189.     bsr    putfile        * save out the file
  190.     move.l    (a7)+,d0    * setup for seek
  191.     bsr    seek        * put cursor back
  192.     rts
  193. *****************************************************************
  194. * ABANDON - abondon file being edited
  195. abandon:
  196.     tst.w    modify(a5)    * check for changes
  197.     bne    sk0_abn        * confirm if modified
  198. lp0_abn:
  199.     clr.l    d0        * mark as don't resume editing
  200.     addq.l    #4,a7        * pop top return address
  201.     rts            * returns to 'edit's caller
  202. sk0_abn:
  203.     move.l    #confirm,a0    * confirm prompt
  204.     move.l    #query,a1    * general purpose response area
  205.     bsr    ask        * check with the human
  206.     and.b    #$5F,query    * make uppercase
  207.     cmp.b    #'Y',query    * test for 'Y' or 'y'
  208.     beq    lp0_abn        * human says ok, so dump it.
  209.     rts            * failed abandon exit
  210. confirm:
  211.     dc.b    'Abandon modified file? (Y/N) ',0
  212.     dc.w    0
  213. *****************************************************************
  214. end_save:
  215.     bsr    putfile        * write the file to disk
  216.     tst.w    d0        * check return code
  217.     bne    sk0_ener    * jump if error
  218.     clr.l    d0        * mark as don't resume editing
  219.     addq.l    #4,a7        * pop top return address
  220.     rts            * returns to caller of EDIT
  221. sk0_ener:
  222.     rts            * and back to edit main loop
  223.  
  224.     end
  225.